Add CustomUpscale postFx to replace upscaler with a custom script

Source/Shaders/MultiScaler.shader

@@ -3,10 +3,8 @@
 #include "./Flax/Common.hlsl"
 
 META_CB_BEGIN(0, Data)
-
 float2 TexelSize;
 float2 Padding;
-
 META_CB_END
 
 // Use linear sampling (less texture fetches required)
@@ -70,7 +68,7 @@ META_PS(true, FEATURE_LEVEL_ES2)
 META_PERMUTATION_1(CONVOLVE_VERTICAL=0)
 META_PERMUTATION_1(CONVOLVE_VERTICAL=1)
 float4 PS_Blur9(Quad_VS2PS input) : SV_Target0
-{	
+{
 	const float offsets[3] = {
 		0.00000000,
 		1.38461538,
@@ -106,7 +104,7 @@ META_PS(true, FEATURE_LEVEL_ES2)
 META_PERMUTATION_1(CONVOLVE_VERTICAL=0)
 META_PERMUTATION_1(CONVOLVE_VERTICAL=1)
 float4 PS_Blur13(Quad_VS2PS input) : SV_Target0
-{	
+{
 	const float offsets[4] = {
 		0.00000000,
 		1.41176471,
@@ -138,3 +136,65 @@ float4 PS_Blur13(Quad_VS2PS input) : SV_Target0
 
 	return color;
 }
+
+// Samples a texture with Catmull-Rom filtering, using 9 texture fetches instead of 16.
+// See http://vec3.ca/bicubic-filtering-in-fewer-taps/ for more details
+// The following code is licensed under the MIT license: https://gist.github.com/TheRealMJP/bc503b0b87b643d3505d41eab8b332ae
+// Source: https://gist.github.com/TheRealMJP/c83b8c0f46b63f3a88a5986f4fa982b1
+float4 SampleTextureCatmullRom(Texture2D tex, SamplerState linearSampler, float2 uv, float2 texelSize)
+{
+    // We're going to sample a a 4x4 grid of texels surrounding the target UV coordinate. We'll do this by rounding
+    // down the sample location to get the exact center of our "starting" texel. The starting texel will be at
+    // location [1, 1] in the grid, where [0, 0] is the top left corner.
+    float2 samplePos = uv / texelSize;
+    float2 texPos1 = floor(samplePos - 0.5f) + 0.5f;
+
+    // Compute the fractional offset from our starting texel to our original sample location, which we'll
+    // feed into the Catmull-Rom spline function to get our filter weights.
+    float2 f = samplePos - texPos1;
+
+    // Compute the Catmull-Rom weights using the fractional offset that we calculated earlier.
+    // These equations are pre-expanded based on our knowledge of where the texels will be located,
+    // which lets us avoid having to evaluate a piece-wise function.
+    float2 w0 = f * (-0.5f + f * (1.0f - 0.5f * f));
+    float2 w1 = 1.0f + f * f * (-2.5f + 1.5f * f);
+    float2 w2 = f * (0.5f + f * (2.0f - 1.5f * f));
+    float2 w3 = f * f * (-0.5f + 0.5f * f);
+
+    // Work out weighting factors and sampling offsets that will let us use bilinear filtering to
+    // simultaneously evaluate the middle 2 samples from the 4x4 grid.
+    float2 w12 = w1 + w2;
+    float2 offset12 = w2 / (w1 + w2);
+
+    // Compute the final UV coordinates we'll use for sampling the texture
+    float2 texPos0 = texPos1 - 1;
+    float2 texPos3 = texPos1 + 2;
+    float2 texPos12 = texPos1 + offset12;
+
+    texPos0 *= texelSize;
+    texPos3 *= texelSize;
+    texPos12 *= texelSize;
+
+    float4 result = 0.0f;
+    result += tex.SampleLevel(linearSampler, float2(texPos0.x, texPos0.y), 0.0f) * w0.x * w0.y;
+    result += tex.SampleLevel(linearSampler, float2(texPos12.x, texPos0.y), 0.0f) * w12.x * w0.y;
+    result += tex.SampleLevel(linearSampler, float2(texPos3.x, texPos0.y), 0.0f) * w3.x * w0.y;
+
+    result += tex.SampleLevel(linearSampler, float2(texPos0.x, texPos12.y), 0.0f) * w0.x * w12.y;
+    result += tex.SampleLevel(linearSampler, float2(texPos12.x, texPos12.y), 0.0f) * w12.x * w12.y;
+    result += tex.SampleLevel(linearSampler, float2(texPos3.x, texPos12.y), 0.0f) * w3.x * w12.y;
+
+    result += tex.SampleLevel(linearSampler, float2(texPos0.x, texPos3.y), 0.0f) * w0.x * w3.y;
+    result += tex.SampleLevel(linearSampler, float2(texPos12.x, texPos3.y), 0.0f) * w12.x * w3.y;
+    result += tex.SampleLevel(linearSampler, float2(texPos3.x, texPos3.y), 0.0f) * w3.x * w3.y;
+
+    return result;
+}
+
+// Pixel Shader for upscaling image
+META_PS(true, FEATURE_LEVEL_ES2)
+float4 PS_Upscale(Quad_VS2PS input) : SV_Target0
+{
+	// Catmull-Rom filtering with 9-taps
+	return SampleTextureCatmullRom(Input, SamplerLinearClamp, input.TexCoord, TexelSize);
+}